*GET FILE=    'U:\Dokumente\Daten_von_v\TEXT\Thyssen2003\Daten\Thyssen2003.sav'.
GET FILE=                                                     'Thyssen2003.sav'.



* AUswahl der Faelle*.
fre linkok.
RECODE linkok  (-99=-999)  .
fre linkok .

fre zusatzin.
RECODE zusatzin  (SYSMIS=-999)  .
fre zusatzin .


*** Erstellung des um Zweifelsfaelle bereinigten Datansatzes fuer die weiteren Analysen ***.
select if (linkok ne 5 and linkok ne 6 and zusatzin ne 3 and zusatzin ne 4). 


fre linkok zusatzin.




**********************************************************************************.
*** Persoenlichkeitseigenschaften (Big 5) *** vgl. zur Skalenbildung Ahnahng 1 ***.
**********************************************************************************.


*** Big Five Persoenlichkeitsskalen ***.

     
corr oe gw vt ex nz                      WITH  bfi_o bfi_c bfi_a bfi_e bfi_n. 
corr kbfi_o kbfi_c kbfi_a kbfi_e kbfi_n  WITH  bfi_o bfi_c bfi_a bfi_e bfi_n. 





******************************************************************************.
*** Werte nach Klages - Faktoren *** vgl. zu "Werten" hierzu auch Anlage 2 ***.
******************************************************************************.
*fre  z1.3.
*des  z1.3   z1.4   z1.5   z1.6   z1.7   z1.8   z1.9   z1.10  z1.11  z1.12  z1.13  z1.14 
     z16.1  z16.2  z16.3  z16.4  z16.5  z16.6  z16.7  z16.8  z16.9  z16.10 z16.11 z16.12 
     z16.13 z16.14 z16.15 z16.16 z16.17 z16.18 z16.19 z16.20 z16.21. 
 
FACTOR
  /VARIABLES z1.3 z1.4 z1.5 z1.6 z1.7 z1.8 z1.9 z1.10 z1.11 z1.12 z1.13 z1.14 
  /MISSING LISTWISE 
  /ANALYSIS  z1.3 z1.4 z1.5 z1.6 z1.7 z1.8 z1.9 z1.10 z1.11 z1.12 z1.13 z1.14 
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

variable labels fac1_1 'Pfl/Konv' fac2_1 'Hed/Mat' fac3_1 'Krit/Eng'.
corr fac1_1 fac2_1 fac3_1.



corr oe gw vt ex nz with fac1_1 fac2_1 fac3_1. 





******************************************************************************.
*** Einstellungen I: Einstellungen zu Politikern wie Merkel bzw. Schroeder ***.
******************************************************************************.

* Merkel*.
corr z10.2 
     z10.1 z10.3 z10.4 z10.5 z10.6 z10.7 z10.8 z10.9 z10.10 z10.11 z10.12 z10.13 z10.14
     z11.8   with fr4_3. 

FACTOR
  /VARIABLES z10.1 z10.3 z10.4 z10.5 z10.6 z10.7 z10.8 z10.9 z10.10 z10.11 z10.12 z10.13 z10.14 z11.8   
  /MISSING LISTWISE 
  /ANALYSIS  z10.1 z10.3 z10.4 z10.5 z10.6 z10.7 z10.8 z10.9 z10.10 z10.11 z10.12 z10.13 z10.14 z11.8   
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

variable labels FAC1_2 'MerkelF1'.

corr FAC1_2 with fr4_3. 

corr FAC1_2 with oe gw vt ex nz. 
corr FAC1_2 with fac1_1 fac2_1 fac3_1. 


* Schroeder *.
corr z9.3 
     z9.2 z9.4 z9.5 z9.6 z9.7 z9.8 z9.9 z9.10 z9.11 z9.12 z9.13 z9.14 z9.15
     z11.6 with fr4_1. 

FACTOR
  /VARIABLES z9.2 z9.4 z9.5 z9.6 z9.7 z9.8 z9.9 z9.10 z9.11 z9.12 z9.13 z9.14 z9.15 z11.6    
  /MISSING LISTWISE 
  /ANALYSIS  z9.2 z9.4 z9.5 z9.6 z9.7 z9.8 z9.9 z9.10 z9.11 z9.12 z9.13 z9.14 z9.15 z11.6    
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

variable labels FAC1_3 'SCHROEF1'.
variable labels FAC2_3 'SCHROEF2'.

corr FAC1_3 FAC2_3  with fr4_1.
 
corr FAC1_3 FAC2_3  with oe gw vt ex nz. 
corr FAC1_3 FAC2_3  with fac1_1 fac2_1 fac3_1. 





***************************************************.
*** Einstellungen II: Einstellungen zu Parteien ***.
***************************************************.

corr fr5_6 fr5_5 fr5_1 fr5_4 fr5_2 fr5_3 fr5_7 fr5_8 fr5_9  WITH oe gw vt ex nz.
corr fr5_6 fr5_5 fr5_1 fr5_4 fr5_2 fr5_3 fr5_7 fr5_8 fr5_9  WITH fac1_1 fac2_1 fac3_1 fr3 fr40_1.

* Zusammenfassung der Information *.
FACTOR
  /VARIABLES fr5_6 fr5_5 fr5_1 fr5_4 fr5_2 fr5_3 fr5_7 fr5_8 fr5_9   
  /MISSING LISTWISE 
  /ANALYSIS  fr5_6 fr5_5 fr5_1 fr5_4 fr5_2 fr5_3 fr5_7 fr5_8 fr5_9   
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .


var labels FAC1_4 'Rechtsextrem'.
var labels FAC2_4 'Konservativ'.
var labels FAC3_4 'Links'.

corr FAC1_4 FAC2_4 FAC3_4 WITH oe gw vt ex nz.
corr FAC1_4 FAC2_4 FAC3_4 WITH fac1_1 fac2_1 fac3_1      fr3 fr40_1.





*****************************************************************.
*** Einstellungen III:  "Auslaenderfreundlich-/feindlichkeit" ***.
*****************************************************************.

* Umkodierung des "Auslaender-Items" (der gesseren Vergleichbarkeit halber) *.
fre    z15.3.
compute Zuzugerl = (z15.3 * (-1)) + 6.
fre     Zuzugerl.
corr    Zuzugerl z15.3.
var labels z15.3 'Zuzug Ausl. erleichtern'.

corr Zuzugerl WITH oe gw vt ex nz.
corr Zuzugerl WITH fac1_1 fac2_1 fac3_1.

 
*des z6.12 z6.13 z6.14 z6.15 z6.16 z6.17 z6.18 z6.20 z6.21. 
FACTOR
  /VARIABLES z6.12 z6.13 z6.14 z6.15 z6.16 z6.17 z6.18 z6.20 z6.21   
  /MISSING LISTWISE 
  /ANALYSIS  z6.12 z6.13 z6.14 z6.15 z6.16 z6.17 z6.18 z6.20 z6.21   
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .


var labels FAC1_5 'fremdKult'.
var labels FAC2_5 'aehnlKult'.

corr FAC1_5 FAC2_5 Zuzugerl WITH oe gw vt ex nz.
corr FAC1_5 FAC2_5 Zuzugerl WITH fac1_1 fac2_1 fac3_1.






* Reliabilität von zwei Instrumenten nach dem Likert-Verfahren *.
*fre   z6.21 z6.20 z6.13 z6.18 z6.17   z6.14 z6.16 z6.12 z6.15.


* Reliabilitaet: Lik_fremd r=.84 *.
RELIABILITY 
  /VARIABLES= z6.21 z6.20 z6.13 z6.18 z6.17   
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

* Reliabilitaet: Lik_aehnl r=.71 *.
RELIABILITY 
  /VARIABLES= z6.14 z6.16 z6.12 z6.15   
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.






* Reliabilitaet: Zuzug Auslaender r=.59 *.
CROSSTABS fr29_4  BY z15.3.
CORR      fr29_4     z15.3. 

* Reliabilitaet: Vertrauen in Gewerkschaften r=.61 *.
CROSSTABS fr10_11 BY z11.2. 
CORR      fr10_11    z11.2.

* Reliabilitaet: Militaereinsatz Irak r=.60 *.
CROSSTABS fr29_1  BY z15.2.
CORR      fr29_1     z15.2. 

* Reliabilitaet: Kernenergie r=.55 *.
CROSSTABS fr29_10  BY z15.1.
CORR      fr29_10     z15.1. 

* Reliabilitaet: Europaeische Einigung r =.56 *.
CROSSTABS fr29_7  BY z15.4.
CORR      fr29_7     z15.4. 


* Reliabilitaet: Sympathie fuer Angela Merkel (Item leicht veraendert) r =.54 *.
CROSSTABS fr4_3  BY z10.2.
CORR      fr4_3     z10.2. 

* Reliabilitaet: Sympathie fuer Gerhard Schroeder (Item leicht veraendert) r =.57 *.
CROSSTABS fr4_1  BY z9.3.
CORR      fr4_1     z9.3. 


* Wissensfragen *.
fre fr24 fr25_1 fr25_2 fr26_1 fr26_2 fr26_3 fr26_4 fr26_5 fr26_6 fr26_7 fr26_8 fr26_9. 








*************************************************************************************************.
*** Einstellungen IV: Rechte / Linke pol. Einstellungen  plus  "Autoritarismus" (Oesterreich) ***.
*************************************************************************************************.

fre fr40_6 fr40_12 fr40_17 fr40_19 fr40_29 fr40_33 fr40_36 fr40_40 fr40_41 fr40_42. 


* REX: Alpha = .78 *.

RELIABILITY
  /VARIABLES= fr40_6 fr40_12 fr40_17        fr40_29 fr40_33 fr40_36 fr40_40 fr40_41 fr40_42
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE REX = means.7(fr40_6, fr40_12, fr40_17,        fr40_29, fr40_33, fr40_36, fr40_40, fr40_41, fr40_42).
var labels REX 'extrem rechte Einstellungen'.
fre     REX.




* LIX: Alpha = .71 *.

fre fr40_9 fr40_10 fr40_14 fr40_22 fr40_28 fr40_32 fr40_35 fr40_37 fr40_39. 

RELIABILITY 
  /VARIABLES= fr40_9 fr40_10 fr40_14 fr40_22        fr40_32 fr40_35 fr40_37 fr40_39
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE LIX = means.7(fr40_9, fr40_10, fr40_14, fr40_22,        fr40_32, fr40_35, fr40_37, fr40_39).
var labels LIX 'extrem linke Einstellungen'.
fre     LIX.




* Autoritarismus-Skala von Oesterreich (AUT): Alpha = .84 *.
fre z7.2.
des z7.2 z7.3 z7.4 z7.5 z7.6 z7.7 z7.8 z7.9 z7.10 z7.11 z7.12 z7.13.
compute recz7.4  = (z7.4  * (-1)) + 4.
compute recz7.7  = (z7.7  * (-1)) + 4.
compute recz7.15 = (z7.15 * (-1)) + 4.
compute recz7.17 = (z7.17 * (-1)) + 4.
compute recz7.18 = (z7.18 * (-1)) + 4.
compute recz8.1  = (z8.1  * (-1)) + 4.
compute recz8.3  = (z8.3  * (-1)) + 4.
compute recz8.6  = (z8.6  * (-1)) + 4.
RELIABILITY
  /VARIABLES=z7.2     z7.3  recz7.4     z7.5     z7.6  recz7.7    z7.8 z7.9 z7.10   z7.11 z7.12 z7.13
             z7.14 recz7.15    z7.16 recz7.17 recz7.18 recz8.1 recz8.3 z8.4 z8.5 recz8.6  z8.8
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /SUMMARY=TOTAL .
COMPUTE  AUTneg = means.18(z7.2,     z7.3,  recz7.4,     z7.5,     z7.6,  recz7.7,    z7.8, z7.9, z7.10,   z7.11, z7.12, z7.13,
                          z7.14, recz7.15,    z7.16, recz7.17, recz7.18, recz8.1, recz8.3, z8.4, z8.5, recz8.6,  z8.8).
des      AUTneg.
compute  AUT    = (AUTneg *(-1)) + 4.
des      AUT AUTneg.
corr     AUT AUTneg.


* Korrelationen *.
fre fr28. 
corr     fr28  WITH  AUT REX LIX .
corr                     REX LIX .

corr     fr28 AUT REX LIX  WITH  oe gw vt ex nz.
corr     fr28 AUT REX LIX  WITH  fac1_1 fac2_1 fac3_1.




**********************.
*** Zusammenhaenge ***.
**********************.


*** Zusammenhang: Autoritarismus --> (extrem) rechte pol. Einstellungen ***.

corr REX AUT.

fre frs16.

temporary.
select if (frs16 gt 1). 
PARTIAL CORR
  /VARIABLES= REX AUT BY frs16
  /SIGNIFICANCE=TWOTAIL
  /STATISTICS=CORR
  /MISSING=LISTWISE. 


temporary.
select if (frs16 eq 2). 
corr REX AUT.
* ohne Abschluss: n=24; r=.43 *.

temporary.
select if (frs16 eq 3). 
corr REX AUT.
* Hauptschulabschluss: n=568; r=.25 *.

temporary.
select if (frs16 eq 4). 
corr REX AUT.
* Realschulabschluss: n=387; r=.26 *.

temporary.
select if (frs16 eq 5). 
corr REX AUT.
* Abitur: n=131; r=.39 *.

temporary.
select if (frs16 eq 6). 
corr REX AUT.
* Hochschulabschluss: n=121; r=.31 *.



*** Zusammenhaenge: Einflussfaktoren auf "Sympathie für die Gruenen" ***.

* "Komplette" Gleichung *.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr5_5 
  /METHOD=ENTER fr4_2 fr4_6 fr29_1 fr29_4 fr29_10 fr32_2 oe gw  .

* 3 x Reduzierte Gleichungen *.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr5_5 
  /METHOD=ENTER fr4_2 fr4_6 fr29_1 fr29_4 fr29_10        oe gw  .

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr5_5  
  /METHOD=ENTER             fr29_1 fr29_4 fr29_10 fr32_2 oe gw  .

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr5_5  
  /METHOD=ENTER             fr29_1 fr29_4 fr29_10        oe gw  .




* "Komplette" Gleichung alternativ: Sympathie mit Zufriedenheit (mit den Gruenen) vertauscht! *.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr32_2 
  /METHOD=ENTER fr4_2 fr4_6 fr29_1 fr29_4 fr29_10 fr5_5 oe gw  .



* "Komplette" Gleichung ergaenzt um Links-Rechts-Selbsteinschaetzung *.
fre fr36. 
if (fr36 eq 6) PI_Gruen = 1.
if (fr36 ne 6) PI_Gruen = 0.
fre            PI_Gruen.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA COLLIN TOL 
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT fr5_5 
  /METHOD=ENTER fr4_2 fr4_6 fr29_1 fr29_4 fr29_10 fr32_2 oe gw  fr28.




****************************************************************************************************.
*** Zusammenhang zwischen Werten und Persoenlichkeitseigenschafen *** --> abgeleitete Hypothesen ***.
****************************************************************************************************.



corr fac1_1 fac2_1 fac3_1  
     fac1_6 fac2_6 fac3_6 fac4_6
WITH  oe gw vt ex nz.


fre  fr3 fr40_1. 

corr fr3 fr40_1. 

corr oe gw vt ex nz with fr3 fr40_1. 














****************************************************************************.
****** Anlage 1: Bildung der Big Five Persoenlichkeitsskalen (plus ASKO) ***.
****************************************************************************.




*** NEO-FFI: Neurotizismus: Alpha = .82 ***.

des fr41_21 fr41_6 fr41_11 fr41_16 fr41_1 fr41_26 fr41_31 fr41_36 fr41_41 fr41_46 fr41_51 fr41_56. 

compute fr41_16r = (fr41_16 * (-1) + 6).
compute fr41_1r  = (fr41_1  * (-1) + 6).
compute fr41_31r = (fr41_31 * (-1) + 6).
compute fr41_46r = (fr41_46 * (-1) + 6).
corr fr41_46 fr41_46r.

RELIABILITY
  /VARIABLES= fr41_21 fr41_6 fr41_11 fr41_16r fr41_1r fr41_26 fr41_31r fr41_36 fr41_41 fr41_46r fr41_51 fr41_56
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE NZ = means.9(fr41_21, fr41_6, fr41_11, fr41_16r, fr41_1r, fr41_26, fr41_31r, fr41_36, fr41_41, fr41_46r, fr41_51, fr41_56).
fre     NZ.



*** NEO-FFI: Extraversion: Alpha = .75 ***.

des fr41_2 fr41_7 fr41_12 fr41_17 fr41_22 fr41_27 fr41_32 fr41_37 fr41_42 fr41_47 fr41_52 fr41_57. 

compute fr41_12r = (fr41_12 * (-1) + 6).
compute fr41_27r = (fr41_27 * (-1) + 6).
compute fr41_42r = (fr41_42 * (-1) + 6).
compute fr41_57r = (fr41_57 * (-1) + 6).
corr fr41_57 fr41_57r.

RELIABILITY
  /VARIABLES= fr41_2 fr41_7 fr41_12r fr41_17 fr41_22 fr41_27r fr41_32 fr41_37 fr41_42r fr41_47 fr41_52 fr41_57r
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE EX = means.9(fr41_22, fr41_7, fr41_12r, fr41_17, fr41_2, fr41_27r, fr41_32, fr41_37, fr41_42r, fr41_47, fr41_52, fr41_57r).
fre     EX.




*** NEO-FFI: Offenheit fuer Erfahrung: Alpha = .65 ***.

des fr41_3 fr41_8 fr41_13 fr41_18 fr41_23 fr41_28 fr41_33 fr41_38 fr41_43 fr41_48 fr41_53 fr41_58. 

compute fr41_3r  = (fr41_3  * (-1) + 6).
compute fr41_8r  = (fr41_8  * (-1) + 6).
compute fr41_18r = (fr41_18 * (-1) + 6).
compute fr41_23r = (fr41_23 * (-1) + 6).
compute fr41_33r = (fr41_33 * (-1) + 6).
compute fr41_38r = (fr41_38 * (-1) + 6).
compute fr41_48r = (fr41_48 * (-1) + 6).
corr fr41_48 fr41_48r.

RELIABILITY
  /VARIABLES= fr41_3r fr41_8r fr41_13 fr41_18r fr41_23r fr41_28 fr41_33r fr41_38r fr41_43 fr41_48r fr41_53 fr41_58
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE OE = means.9(fr41_3r, fr41_8r, fr41_13, fr41_18r, fr41_23r, fr41_28, fr41_33r, fr41_38r, fr41_43, fr41_48r, fr41_53, fr41_58).
fre     OE.




*** NEO-FFI: Vertraeglichkeit: Alpha = .73 ***.

des fr41_4 fr41_9 fr41_14 fr41_19 fr41_24 fr41_29 fr41_34 fr41_39 fr41_44 fr41_49 fr41_54 fr41_59. 

compute fr41_4r  = (fr41_4 * (-1) + 6).
compute fr41_19r = (fr41_19 * (-1) + 6).
compute fr41_34r = (fr41_34 * (-1) + 6).
compute fr41_49r = (fr41_49 * (-1) + 6).
corr fr41_4 fr41_4r.

RELIABILITY
  /VARIABLES= fr41_4r fr41_9 fr41_14 fr41_19r fr41_24 fr41_29 fr41_34r fr41_39 fr41_44 fr41_49r fr41_54 fr41_59
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE antiVT = means.9(fr41_4r, fr41_9, fr41_14, fr41_19r, fr41_24, fr41_29, fr41_34r, fr41_39, fr41_44, fr41_49r, fr41_54, fr41_59).
fre     antiVT.

Compute     VT = (antiVT * (-1) + 6).
fre VT antiVT.
corr VT antiVT.



*** NEO-FFI: Gewissenhaftigkeit: Alpha = .84 ***.

des fr41_5 fr41_10 fr41_15 fr41_20 fr41_25 fr41_30 fr41_35 fr41_40 fr41_45 fr41_50 fr41_55 fr41_60. 

compute fr41_15r = (fr41_15 * (-1) + 6).
compute fr41_30r = (fr41_30 * (-1) + 6).
compute fr41_45r = (fr41_45 * (-1) + 6).
compute fr41_55r = (fr41_55 * (-1) + 6).
corr fr41_55 fr41_55r.

RELIABILITY
  /VARIABLES= fr41_5 fr41_10 fr41_15r fr41_20 fr41_25 fr41_30r fr41_35 fr41_40 fr41_45r fr41_50 fr41_55r fr41_60
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE GW = means.9(fr41_5, fr41_10, fr41_15r, fr41_20, fr41_25, fr41_30r, fr41_35, fr41_40, fr41_45r, fr41_50, fr41_55r, fr41_60).
fre     GW.


VAR LAB  NZ "NEO-FFI: Neurotizismus"
        /EX "NEO-FFI: Extraversion"
        /OE "NEO-FFI: Offenheit f. Erfahrung"
        /VT "NEO-FFI: Vertraeglichkeit"
        /GW "NEO-FFI: Gewissenhaftigkeit".
des NZ EX OE VT GW.





**** BFI (Originalfassung / Uebersetzt) *******.
* UMPOLUNG DER ITEMS *.
COMPUTE z12.2r = 5-z12.2.
COMPUTE z12.6r = 5-z12.6.
COMPUTE z12.8r = 5-z12.8.
COMPUTE z12.9r = 5-z12.9.
COMPUTE z12.12r = 5-z12.12.
COMPUTE z12.18r = 5-z12.18.
COMPUTE z12.21r = 5-z12.21.
COMPUTE z12.23r = 5-z12.23.
COMPUTE z12.24r = 5-z12.24.
COMPUTE z12.27r = 5-z12.27.
COMPUTE z12.31r = 5-z12.31.
COMPUTE z12.34r = 5-z12.34.
COMPUTE z12.35r = 5-z12.35.
COMPUTE z12.37r = 5-z12.37.
COMPUTE z12.41r = 5-z12.41.
COMPUTE z12.43r = 5-z12.43.

COMPUTE BFI_E=mean(z12.1, z12.6r, z12.11, z12.16, z12.21r, z12.26, z12.31r, z12.36).
COMPUTE BFI_A=mean(z12.2r, z12.7, z12.12r, z12.17, z12.22, z12.27r, z12.32, z12.37r).
COMPUTE BFI_C=mean(z12.3, z12.8r, z12.13, z12.18r, z12.23r, z12.28, z12.33, z12.38, z12.43r).
COMPUTE BFI_N=mean(z12.4, z12.9r, z12.14, z12.19, z12.24r, z12.29, z12.34r, z12.39).
COMPUTE BFI_O=mean(z12.5, z12.10, z12.15, z12.20, z12.25, z12.30, z12.35r, z12.40, z12.41r, z12.44).

VAR LAB  BFI_N "BFI:Neurotizismus 8 Items"
        /BFI_E "BFI:Extraversion 8 Items"
        /BFI_O "BFI:Offenheit f. Erfahrung 10 Items"
        /BFI_A "BFI:Vertraeglichkeit 8 Items"
        /BFI_C "BFI:Gewissenhaftigkeit 9 Items".

* BFI-Extraversion: Alpha=.81 *.
RELIAB VAR z12.1, z12.6r, z12.11, z12.16, z12.21r, z12.26, z12.31r, z12.36
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
 
* BFI-Vertraeglichkeit: Alpha=.75 *.
RELIAB VAR z12.2r, z12.7, z12.12r, z12.17, z12.22, z12.27r, z12.32, z12.37r
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
 
* BFI-Gewissenhaftigkeit: Alpha=.80 *.
RELIAB VAR z12.3, z12.8r, z12.13, z12.18r, z12.23r, z12.28, z12.33, z12.38, z12.43r
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
 
* BFI-Neurotizismus: Alpha=.74 *.
RELIAB VAR z12.4, z12.9r, z12.14, z12.19, z12.24r, z12.29, z12.34r, z12.39
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.
 
* BFI-Offenheit fuer Erfahrung: Alpha=.82 *.
RELIAB VAR z12.5, z12.10, z12.15, z12.20, z12.25, z12.30, z12.35r, z12.40, z12.41r, z12.44
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.






**** BFI (Kurzskala) *******.
* UMPOLUNG DER ITEMS *.
COMPUTE fr9_6r=6-fr9_6.
COMPUTE fr9_2r=6-fr9_2.
COMPUTE fr9_8r=6-fr9_8.
COMPUTE fr9_9r=6-fr9_9.
COMPUTE fr9_14r=6-fr9_14.
COMPUTE fr9_10r=6-fr9_10.

COMPUTE KBFI_N=mean(fr9_4,fr9_9r, fr9_14r).
COMPUTE KBFI_E=mean(fr9_1 , fr9_6r, fr9_11 ).
COMPUTE KBFI_O=mean(fr9_5, fr9_10r, fr9_15 ).
COMPUTE KBFI_A=mean( fr9_2r, fr9_7, fr9_12 ).
COMPUTE KBFI_C=mean( fr9_3,  fr9_8r, fr9_13 ).

VAR LAB KBFI_N "Neurozizismus - Kurz BFI, 3 Items"
        /KBFI_E "Extraversion - Kurz-BFI, 3 Items"
        /KBFI_O "Offenheit für Erfahrung - Kurz-BFI, 3 Items"
        /KBFI_A "Vertraeglichkeit - Kurz-BFI, 3 Items"
        /KBFI_C "Gewissenhaftigkeit - Kurz-BFI, 3 Items".

fre KBFI_N to KBFI_C.


* BFI-Kursskala "Neurotizismus": Alpha=.58 *.
RELIABILITY /VARIABLES=fr9_4,fr9_9r, fr9_14r  /FORMAT=LABELS  /SCALE(ALPHA)=ALL/MODEL=ALPHA.

* BFI-Kursskala "Extraversion": Alpha=.56 *.
RELIABILITY /VARIABLES=fr9_1  fr9_6r fr9_11 /FORMAT=LABELS  /SCALE(ALPHA)=ALL/MODEL=ALPHA.

* BFI-Kursskala "Offenheit fuer Erfahrung": Alpha=.53 *.
RELIABILITY /VARIABLES=fr9_5 fr9_10r fr9_15 /FORMAT=LABELS  /SCALE(ALPHA)=ALL/MODEL=ALPHA.

* BFI-Kursskala "Vertraeglichkeit": Alpha=.63 *.
RELIABILITY /VARIABLES=fr9_2r fr9_7 fr9_12 /FORMAT=LABELS  /SCALE(ALPHA)=ALL/MODEL=ALPHA.

* BFI-Kursskala "Gewissenhaftigkeit": Alpha=.58 *.
RELIABILITY /VARIABLES=fr9_3  fr9_8r fr9_13 /FORMAT=LABELS  /SCALE(ALPHA)=ALL/MODEL=ALPHA.



corr kbfi_n kbfi_e kbfi_o kbfi_a kbfi_c  WITH  bfi_n bfi_e bfi_o bfi_a bfi_c. 








*** ASKO ***.
des fr7_1 fr7_2 fr7_3 fr7_4 fr7_5 fr7_6 fr7_7 fr7_8 fr7_9.

if (fr7_1 eq 0)ASKO1 = 0.
if (fr7_1 eq 1)ASKO1 = 1.

if (fr7_2 eq 0)ASKO2 = 0.
if (fr7_2 eq 1)ASKO2 = 1.

if (fr7_3 eq 0)ASKO3 = 0.
if (fr7_3 eq 1)ASKO3 = 1.

if (fr7_4 eq 0)ASKO4 = 1.
if (fr7_4 eq 1)ASKO4 = 0.

if (fr7_5 eq 0)ASKO5 = 1.
if (fr7_5 eq 1)ASKO5 = 0.

if (fr7_6 eq 0)ASKO6 = 0.
if (fr7_6 eq 1)ASKO6 = 1.

if (fr7_7 eq 0)ASKO7 = 1.
if (fr7_7 eq 1)ASKO7 = 0.

if (fr7_8 eq 0)ASKO8 = 0.
if (fr7_8 eq 1)ASKO8 = 1.

if (fr7_9 eq 0)ASKO9 = 1.
if (fr7_9 eq 1)ASKO9 = 0.

corr fr7_1 to fr7_9 with ASKO1 to ASKO9.

temporary.
select if (frs18 eq 2).

RELIABILITY
  /VARIABLES= ASKO1 to ASKO9
  /FORMAT=NOLABELS
  /SCALE(ALPHA)=ALL/MODEL=ALPHA
  /STATISTICS=DESCRIPTIVE SCALE
  /SUMMARY=TOTAL MEANS.

COMPUTE ASKO = (means.6(ASKO1, ASKO2, ASKO3, ASKO4, ASKO5, ASKO6, ASKO7, ASKO8, ASKO9) * 9).
fre     ASKO.
des     ASKO.














********************************************************************************************.
*** Anlage 2: Werte-Faktoren ueber die Schwartz-Items plus Bildung des Inglehart-Indexes ***.
********************************************************************************************.



*** Schwartz - Faktoren ***.
*fre  z16.1.
*des  z16.1  z16.2  z16.3  z16.4  z16.5  z16.6  z16.7  z16.8  z16.9  z16.10 
             z16.11 z16.12 z16.13 z16.14 z16.15 z16.16 z16.17 z16.18 z16.19 z16.20 z16.21. 

FACTOR
  /VARIABLES z16.1  z16.2  z16.3  z16.4  z16.5  z16.6  z16.7  z16.8  z16.9  z16.10 
             z16.11 z16.12 z16.13 z16.14 z16.15 z16.16 z16.17 z16.18 z16.19 z16.20 z16.21 
  /MISSING LISTWISE 
  /ANALYSIS  z16.1  z16.2  z16.3  z16.4  z16.5  z16.6  z16.7  z16.8  z16.9  z16.10 
             z16.11 z16.12 z16.13 z16.14 z16.15 z16.16 z16.17 z16.18 z16.19 z16.20 z16.21 
  /PRINT EXTRACTION ROTATION
  /FORMAT SORT
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PAF
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /SAVE REG(ALL)
  /METHOD=CORRELATION .

variable labels fac1_6 'Sich/Konv' fac2_6 'Altr/Eng' fac3_6 'Leist/Anerk' fac4_6 'Hed/Abent'.
corr fac1_6 fac2_6 fac3_6 fac4_6 .


* Korr fuer Klages- und Schwartz-Faktoren *.
corr fac1_1 fac2_1 fac3_1  WITH  fac1_6 fac2_6 fac3_6 fac4_6.


*** Inglehart ***.
fre fr2a fr2b. 
compute PM = -99.
if (fr2a eq 2 and fr2b eq 4)PM = 3.
if (fr2a eq 4 and fr2b eq 2)PM = 3.
if (fr2a eq 1 and fr2b eq 3)PM = 0.
if (fr2a eq 3 and fr2b eq 1)PM = 0.
if (fr2a eq 1 and fr2b eq 2)PM = 1.
if (fr2a eq 1 and fr2b eq 4)PM = 1.
if (fr2a eq 2 and fr2b eq 1)PM = 2.
if (fr2a eq 2 and fr2b eq 3)PM = 2.
if (fr2a eq 3 and fr2b eq 2)PM = 1.
if (fr2a eq 3 and fr2b eq 3)PM = 1.
if (fr2a eq 4 and fr2b eq 1)PM = 2.
if (fr2a eq 4 and fr2b eq 3)PM = 2.
missing values PM (-99).
value labels   PM 0 'Mat' 1 'Mat-Mix' 2 'PostMat-Mix' 3 'PostMat'.
fre PM.

* Korr Klages- und Schwartz-Faktoren mit PM *.
corr fac1_1 fac2_1 fac3_1   fac1_6 fac2_6 fac3_6 fac4_6  WITH  PM.


.